Excel VBA PowerQueryで作ったテーブルのフォーマットを調整するマクロ

PowerQueryのデータをExcelのテーブルに出力すると、こんな感じのフォーマットで出される。

背景色が緑色基調で、横方向1行おきに縞模様が付けられている。環境によって違いがあるのか知らないが、だいたい同じだろう。

このデフォルトのテーブルは、私は好きではない。理由は次のような感じ。

タイトルの文字色が白で、見づらい。
縞模様は要らない。背景色は自分で必要なところに付けたい。
行の高さが低く、文字列の折返し表示に不向き。
データを更新すると列幅を自動調整するオプションが入っているのだが、それが余計。

そこで私は、PowerQueryから作ったテーブルについて、サクッと調整するマクロを作成し、個人用マクロブックに組み込んでいる。

個人用マクロブックとかについては、ここを展開。

オリジナルのマクロをリボンに追加する方法はこちら。

個人用マクロブックについては、こちらやこちらで述べています。

Sub adjustPowerQueryTable()
'PowerQueryで作成したテーブルのフォーマット調整
    Dim ws      As Worksheet: Set ws = ActiveSheet
    Dim LO      As ListObject

    Set LO = ws.ListObjects(1) 'テーブル

    With ws
        .PageSetup.PrintTitleRows = "$1:$1" '印刷タイトル行
        .Cells.RowHeight = 24 '行の高さ
        .Cells.Font.Size = 9  'フォントサイズ
    End With

    '見出し行について設定
    With ws.Rows(1)
        '縦・横中央揃え
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        '文字列を折り返す
        .WrapText = True
    End With

    With LO
        .QueryTable.AdjustColumnWidth = False '列幅の自動調整OFF
        .TableStyle = "TableStyleLight18" 'テーブルスタイルをシンプルなものに
        .ShowTableStyleRowStripes = False '縞模様なし
        .HeaderRowRange.Interior.Color = 65535 '見出し行の背景色を黄色に
    End With
    
    ActiveWindow.DisplayGridlines = False '枠線を非表示
End Sub