Excel VBA PDF変換をもっと更に簡単に済ませよう個人用マクロブックに組み込めるマクロ

Excel→PDF変換も面倒

Excel 印刷設定を頑張りすぎない～複数シート印刷ならPDF変換で楽にやろう～

2020年3月20日

以前に、Excelで印刷設定をあれこれ頑張るくらいなら、まずPDF変換してから印刷しようという記事を書いた。

ただこの方法も、何度もやってくると結構カッタるい。

ExcelシートをPDF変換するにあたって、最短手順でやっても

①F12キー(名前を付けて保存)
②ファイルの保存形式で、一覧の中でかなり下の方にある「PDF」を選択する

という手順が必要で、特に②がまどろっこしい。

特に動作の遅いPCを使ってる人なんかは、①での応答時間が長くて②になかなか行けないだろうし、②で一覧から「PDF」を選ぶのもチマチマ面倒だろう。

あくまで、印刷程度のことでイチイチ時間を掛けたくない、楽をしたいのだ。

印刷する前にPDF変換というプロセスを踏むのは何とか譲るとして、その度に面倒なマウス操作とかを毎回しているわけにはいかない。

即PDF変換するマクロ

そこで私は、下記のマクロをExcelの個人用マクロブックに組み込んで使用している。

Sub quickPDFSave()
'選択されたシートを、ダイアログ等省略して即PDF変換する

    With Application
        .ScreenUpdating = False '描画省略
        .DisplayAlerts = False  '警告省略
    End With
    
    Dim wb                  As Workbook
    Dim myPath              As String
    Dim PDFFileName         As String
    Dim num                 As Long
    
    Set wb = ActiveWorkbook
    
    'まずExcelファイル名を取得。
    '取得結果：「ファイル.xlsx」といった名前。
    PDFFileName = wb.Name
    
    
    '拡張子の「.」文字がある位置
    num = InStrRev(PDFFileName, ".")
    
    If num > 0 Then '拡張子がある→保存されているExcelファイルである場合
        '拡張子の「.」文字以前のファイル名のみ取得。
        '取得結果：「ファイル.xlsx」→「ファイル」といった名前に変換される。
        PDFFileName = Left(PDFFileName, num - 1)
        myPath = wb.Path
    Else '拡張子がない→未保存のExcelファイルである場合
        '保存フォルダを選ばせる
        With Application.FileDialog(msoFileDialogFolderPicker)
            .Filters.Clear
            .Title = "保存フォルダの選択"
            If Not .Show Then Exit Sub
            myPath = .SelectedItems(1) '保存フォルダ
        End With
        
    End If
    
    
    '保存するPDFのファイル名。現在時刻を付ける。
    PDFFileName = myPath & "\" & PDFFileName & Format$(Now, "_yyyy年mm月dd日hh時mm分ss秒") & ".pdf"
    
    'PDF変換
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PDFFileName
    
    With Application
        .ScreenUpdating = True '描画再開
        .DisplayAlerts = True  '警告再開
    End With
    
    
    '作成したPDFファイルを開く
    CreateObject("Shell.Application").ShellExecute PDFFileName
End Sub