Excel VBA 全てのシートの余白設定を統一するマクロ

Excelで多数のシートがあるとき、それらの余白設定を、全シートについて統一したいということは多い。

そういう場合、

シート見出しを右クリック→「すべてのシートを選択」
複数シート見出しをShiftキーやCtrlキーで選択

とかで複数シートを選択してからページ設定メニューを使えば、その余白の統一設定じたいはできる。

しかしそうすると、

シートによって、印刷方向を縦/横と分けたい
シートによって、用紙サイズをA4/A3などと分けたい

という場合にも、それら設定までまとめて統一されてしまう。

Excel ページ設定の基本機能③ページ設定ダイアログの「シート」タブ

2020年3月21日

Excel ページ設定の基本機能②ページ設定ダイアログから

2020年3月22日

Excel ページ設定の基本機能①印刷タイトルの設定

2020年3月21日

あくまでも、余白設定だけを統一したいということで、この場合はマクロを使えば便利だ。

下記にソースコードを示す。自動記録をヒントに作れる簡単な即席マクロだ。

個人用マクロブックに組み込むと良いだろう。

個人用マクロブックとかについては、ここを展開。

オリジナルのマクロをリボンに追加する方法はこちら。

個人用マクロブックについては、こちらやこちらで述べています。

Sub unifyMargins()
'全シートの余白を統一

    If MsgBox("全シートの余白をアクティブシートに合わせ統一しますか？", vbQuestion + vbOKCancel, "確認") = vbCancel Then Exit Sub

    Dim leftMg		'左余白
    Dim rightMg     '右余白
    Dim topMg       '上余白
    Dim bottomMg    '下余白
    Dim headerMg    'ヘッダー
    Dim footerMg    'フッター

    Application.ScreenUpdating = False

    'アクティブシートの余白を取得
    With ActiveSheet.PageSetup
        leftMg = .LeftMargin		'左余白
        rightMg = .RightMargin    	'右余白
        topMg = .TopMargin        	'上余白
        bottomMg = .BottomMargin  	'下余白
        headerMg = .HeaderMargin  	'ヘッダー
        footerMg = .FooterMargin  	'フッター
    End With

    Dim eachWs  As Worksheet
    
    '取得した余白を全シートに適用
    For Each eachWs In Worksheets
        With eachWs.PageSetup
            .LeftMargin = leftMg     '左余白
            .RightMargin = rightMg   '右余白
            .TopMargin = topMg       '上余白
            .BottomMargin = bottomMg '下余白
            .HeaderMargin = headerMg 'ヘッダー
            .FooterMargin = footerMg 'フッター
        End With
    Next eachWs
End Sub